【MacOS10.13以前対応】Kindle等電子書籍を自動スクショでPDF化

use scripting additions
use framework "Foundation"
global aRawimg, desktopHeight, hoseiX, hoseiY

display dialog "スクショする回数を入力してください。" default answer "5" with title "xxxxxx Version"
set screenShotNumber to text returned of result

display dialog "右開き？左開き？" buttons {"左", "右"} default button 2 with title "xxxxxx Version"
set temp to result
set btn to button returned of temp


--左上のポジション取得
display dialog "スクショ範囲 左上" & return & "次の秒数後までにマウスを移動させてください。" default answer "5" with title "？秒後に位置計測"
set screenShotSeconds to text returned of result

delay screenShotSeconds --|開始まで5秒間待ちます、この間に測定したい位置にマウスポインタを移動してください|
(* (1) マウスポインターの位置を取得します *)
set {x, y} to my mousePosition()
do shell script "afplay /System/Library/Sounds/Purr.aiff"


--右下のポジション取得
display dialog "スクショ範囲 右下" & return & "次の秒数後までにマウスを移動させてください。" default answer "5" with title "？秒後に位置計測"
set screenShotSeconds to text returned of result
delay screenShotSeconds --|開始まで5秒間待ちます、この間に測定したい位置にマウスポインタを移動してください|
set {x2, y2} to my mousePosition()
do shell script "afplay /System/Library/Sounds/Purr.aiff"


display dialog "スクショ範囲" & return & "左上座標 X" & return & return & "↓上書きで補正できます" default answer x with title "左上 X位置の補正ができます"
set x to text returned of result
display dialog "スクショ範囲" & return & "左上座標 Y" & return & return & "↓上書きで補正できます" default answer y with title "左上　Y位置の補正ができます"
set y to text returned of result
display dialog "スクショ範囲" & return & "右下座標 X" & return & return & "↓上書きで補正できます" default answer x2 with title "右下 X位置の補正ができます"
set x2 to text returned of result
display dialog "スクショ範囲" & return & "右下座標 Y" & return & return & "↓上書きで補正できます" default answer y2 with title "右下　Y位置の補正ができます"
set y2 to text returned of result


display dialog "左上Position (" & x & "," & y & ")" & return & "右下Position (" & x2 & "," & y2 & ")" with title "スクショ範囲　最終確認"

--始点のセット(x,y)始点からの距離の計算（x2-x,y2-y)
set screenX to x
set screenY to y
set screenWidth to x2 - x
set screenHeight to y2 - y

set dFolder to "~/Desktop/screencapture/"

repeat with p from 1 to screenShotNumber
	
	tell application "Kindle" --ここにはアプリケーション名を記述してください。SafariとかKindxとか
		
		activate
		
		tell application "System Events"
			
			
			if p = 1 then
				delay 1
				
				do shell script ("screencapture -R " & screenX & "," & screenY & "," & screenWidth & "," & screenHeight & " " & dFolder & "0.png")
			end if
			
			--key code 123
			if btn = "右" then
				keystroke (ASCII character 29) -- ページ右送り (カーソルキー)
			else --左
				keystroke (ASCII character 28) -- ページ左送り (カーソルキー)
			end if
			
			delay 1
			do shell script ("screencapture -R " & screenX & "," & screenY & "," & screenWidth & "," & screenHeight & " " & dFolder & p & ".png")
			delay 1
			
		end tell
		
	end tell
	
end repeat

tell me
	activate
	display alert "処理が終了しました。"
end tell

on mousePosition()
	set mouseLocate to current application's class "NSEvent"'s mouseLocation() --|現在のマウス位置を記録|
	
	try --|デスクトップの高さの変数desktopHeightに数値が設定されていなければ、再設定をする |
		desktopHeight as integer
	on error
		set desktopHeight to (word 4 of (do shell script "/usr/sbin/system_profiler SPDisplaysDataType | grep Resolution | tail -n 1")) as integer
	end try
	
	try --|マウス位置の数値上のズレを記録した変数が設定されていなければ、再設定する|		
		{hoseiX as integer, hoseiY as integer}
	on error
		(* ポインタを測定原点位置に移動してから、位置を測定しズレを確認。補正変数に記録します *)
		set pt to {x:100, y:100}
		tell current application to CGPostMouseEvent(pt, 1, 1, 0)
		set mouseLoc to current application's class "NSEvent"'s mouseLocation()
		set x1 to (x of mouseLoc) as integer
		set y1 to desktopHeight - ((y of mouseLoc) as integer)
		set pt to {x:x1, y:y1}
		tell current application to CGPostMouseEvent(pt, 1, 1, 0)
		set mouseLoc to current application's class "NSEvent"'s mouseLocation()
		set x2 to (x of mouseLoc) as integer
		set y2 to desktopHeight - ((y of mouseLoc) as integer)
		set {hoseiX, hoseiY} to {(x2 - x1), (y2 - y1)}
	end try
	
	(* マウスポインターの位置を補正を反映して元の位置に戻します *)
	set mouseX to ((x of mouseLocate) as integer) - hoseiX
	set mouseY to desktopHeight - ((y of mouseLocate) as integer) - hoseiY
	set pt to {x:mouseX, y:mouseY}
	tell current application to CGPostMouseEvent(pt, 1, 1, 0)
	return {mouseX, mouseY}
	
end mousePosition

tell application "Kindle" --ここにはアプリケーション名を記述してください。SafariとかKindxとか

tell application "safari" --ここにはアプリケーション名を記述してください。SafariとかKindxとか

tell application "honto" --ここにはアプリケーション名を記述してください。SafariとかKindxとか