Power AutomateでWindows Kindleスクショ自動化してみた

# Kindleアプリが起動されているかの簡易チェック
UIAutomation.FocusWindow.Focus Window: appmask['Window \'Kindle\'']
ON ERROR
    SET appStatsError TO $'''notRunStat'''
END
IF appStatsError = $'''notRunStat''' THEN
    Display.ShowMessageDialog.ShowMessage Title: $'''Kindleアプリが起動確認''' Message: $'''Kindleアプリが起動していません。起動後再度処理してください。''' Icon: Display.Icon.None Buttons: Display.Buttons.OK DefaultButton: Display.DefaultButton.Button1 IsTopMost: True ButtonPressed=> ButtonPressed
    EXIT Code: 0
END
# DesktopにscreenshotFolderが存在しているかのチェックと作成指示
Folder.GetSpecialFolder SpecialFolder: Folder.SpecialFolder.DesktopDirectory SpecialFolderPath=> SpecialDesktopPath
IF (Folder.IfFolderExists.DoesNotExist Path: $'''%SpecialDesktopPath%\\screenshotFolder''') THEN
    Display.ShowMessageDialog.ShowMessage Title: $'''デスクトップにscreenshotFolderが存在しません。''' Message: $'''デスクトップにscreenshotFolderが存在しません。　　　　「はい」作成　「いいえ」終了''' Icon: Display.Icon.Question Buttons: Display.Buttons.YesNo DefaultButton: Display.DefaultButton.Button1 IsTopMost: True ButtonPressed=> folderCreateFlag
    IF folderCreateFlag = $'''Yes''' THEN
        Folder.Create FolderPath: SpecialDesktopPath FolderName: $'''screenshotFolder''' Folder=> NewFolder
    ELSE
        EXIT Code: 0
    END
END
# スクリーンショット回数の指定、電子書籍のページ数を入力してもらう。
Display.InputDialog Title: $'''スクショ回数を指定''' Message: $'''スクショ回数''' DefaultValue: 5 InputType: Display.InputType.SingleLine IsTopMost: True UserInput=> screenshotNumber ButtonPressed=> scCountButton
IF scCountButton = $'''Cancel''' THEN
    EXIT Code: 0
END
# 電子書籍が左開きか右開きかの選択
Display.SelectFromListDialog.SelectFromList Title: $'''ページ開き方向指定''' Message: $'''「左開き」か「右開き」を指定してください。''' List: $'''左開き
右開き''' IsTopMost: False AllowEmpty: False SelectedItem=> SelectedPageDirection SelectedIndex=> SelectedIndex ButtonPressed=> LRButtonFlag
IF LRButtonFlag = $'''Cancel''' THEN
    EXIT Code: 0
END
# スクリーンショット処理主要部
UIAutomation.FocusWindow.Focus Window: appmask['Window \'Kindle\'']
ON ERROR
    SET appStatsError TO $'''notRunStat'''
END
WAIT 3
Text.ToNumber Text: screenshotNumber Number=> TextAsNumber
SET loopCounter TO 1
SET createedFileNamer TO $'''sampleFileName_'''
LOOP WHILE (loopCounter) <= (TextAsNumber)
    SET pngFileNameBase TO $'''%createedFileNamer + loopCounter%.png'''
    Workstation.TakeScreenshot.TakeScreenshotOfForegroundWindowAndSaveToFile File: $'''%SpecialDesktopPath%\\screenshotFolder\\%pngFileNameBase%''' ImageFormat: System.ImageFormat.Png
    Workstation.PlaySound.PlaySystemSound SystemSound: System.SystemSound.Hand
    WAIT 1
    IF SelectedPageDirection = $'''右開き''' THEN
        MouseAndKeyboard.SendKeys.FocusAndSendKeys TextToSend: $'''{Right}''' DelayBetweenKeystrokes: 10 SendTextAsHardwareKeys: False
    ELSE
        MouseAndKeyboard.SendKeys.FocusAndSendKeys TextToSend: $'''{Left}''' DelayBetweenKeystrokes: 10 SendTextAsHardwareKeys: False
    END
    WAIT 1
    SET loopCounter TO loopCounter + 1
END
Display.ShowMessageDialog.ShowMessage Title: $'''処理終了''' Message: $'''処理が終了しました。保存されたファイルをご確認ください。''' Icon: Display.Icon.None Buttons: Display.Buttons.OK DefaultButton: Display.DefaultButton.Button1 IsTopMost: True ButtonPressed=> ButtonPressed2